// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

// ════════════════════════════════════════════════ INTERFACES ═════════════════════════════════════════════════════

import {ISynapseIntentRouter} from "../interfaces/ISynapseIntentRouter.sol";
import {ISynapseIntentRouterErrors} from "../interfaces/ISynapseIntentRouterErrors.sol";
import {IZapRecipient} from "../interfaces/IZapRecipient.sol";

// ═════════════════════════════════════════════ EXTERNAL IMPORTS ══════════════════════════════════════════════════

import {IERC20, SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {Address} from "@openzeppelin/contracts/utils/Address.sol";

contract SynapseIntentRouter is ISynapseIntentRouter, ISynapseIntentRouterErrors {
    using SafeERC20 for IERC20;

    /// @notice The address reserved for the native gas token (ETH on Ethereum and most L2s, AVAX on Avalanche, etc.).
    address public constant NATIVE_GAS_TOKEN = 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE;

    /// @dev Amount value that signals that the Zap step should be performed using the full ZapRecipient balance.
    uint256 internal constant FULL_BALANCE = type(uint256).max;

    /// @inheritdoc ISynapseIntentRouter
    function completeIntentWithBalanceChecks(
        address zapRecipient,
        uint256 amountIn,
        uint256 deadline,
        StepParams[] calldata steps
    )
        external
        payable
    {
        // Record the initial balances of ZapRecipient for each token.
        uint256 length = steps.length;
        uint256[] memory initialBalances = new uint256[](length);
        for (uint256 i = 0; i < length; i++) {
            address token = steps[i].token;
            initialBalances[i] =
                token == NATIVE_GAS_TOKEN ? zapRecipient.balance : IERC20(token).balanceOf(zapRecipient);
        }

        // Complete the intent as usual.
        completeIntent(zapRecipient, amountIn, deadline, steps);

        // Verify that the ZapRecipient balance for each token has not increased.
        for (uint256 i = 0; i < length; i++) {
            address token = steps[i].token;
            uint256 newBalance =
                token == NATIVE_GAS_TOKEN ? zapRecipient.balance : IERC20(token).balanceOf(zapRecipient);
            if (newBalance > initialBalances[i]) revert SIR__UnspentFunds();
        }
    }

    /// @inheritdoc ISynapseIntentRouter
    function completeIntent(
        address zapRecipient,
        uint256 amountIn,
        uint256 deadline,
        StepParams[] calldata steps
    )
        public
        payable
    {
        // Validate the input parameters before proceeding.
        uint256 length = steps.length;
        if (block.timestamp > deadline) revert SIR__DeadlineExceeded();
        if (length == 0) revert SIR__StepsNotProvided();

        // Transfer the input asset from the user to ZapRecipient. `steps[0]` exists as per check above.
        _transferInputAsset(zapRecipient, steps[0].token, amountIn);

        // Perform the Zap steps, using predetermined amounts or the full balance of ZapRecipient, if instructed.
        uint256 totalUsedMsgValue = 0;
        for (uint256 i = 0; i < length; i++) {
            address token = steps[i].token;
            uint256 msgValue = steps[i].msgValue;

            // Adjust amount to be the full balance, if needed.
            amountIn = steps[i].amount;
            if (amountIn == FULL_BALANCE) {
                amountIn = token == NATIVE_GAS_TOKEN
                    // Existing native balance + msg.value that will be forwarded
                    ? zapRecipient.balance + msgValue
                    : IERC20(token).balanceOf(zapRecipient);
            }

            _performZap({
                zapRecipient: zapRecipient,
                msgValue: msgValue,
                zapRecipientCallData: abi.encodeCall(IZapRecipient.zap, (token, amountIn, steps[i].zapData))
            });
            unchecked {
                // Can do unchecked addition here since we're guaranteed that the sum of all msg.value
                // used for the Zaps won't overflow.
                totalUsedMsgValue += msgValue;
            }
        }

        // Verify that we fully spent `msg.value`.
        if (totalUsedMsgValue < msg.value) revert SIR__MsgValueIncorrect();
    }

    // ═════════════════════════════════════════════ INTERNAL METHODS ══════════════════════════════════════════════════

    /// @notice Transfers the input asset from the user into ZapRecipient custody. This asset will later be
    /// used to perform the zap steps.
    function _transferInputAsset(address zapRecipient, address token, uint256 amount) internal {
        if (token == NATIVE_GAS_TOKEN) {
            // For the native gas token, we just need to check that the supplied `msg.value` is correct.
            // We will later forward `msg.value` in the series of the steps using `StepParams.msgValue`.
            if (amount != msg.value) revert SIR__MsgValueIncorrect();
        } else {
            // For ERC20s, token is transferred from the user to ZapRecipient before performing the zap steps.
            // Throw an explicit error if the provided token address is not a contract.
            if (token.code.length == 0) revert SIR__TokenNotContract();
            IERC20(token).safeTransferFrom(msg.sender, zapRecipient, amount);
        }
    }

    /// @notice Performs a Zap step, using the provided msg.value and calldata.
    /// Validates the return data from ZapRecipient as per `IZapRecipient` specification.
    function _performZap(address zapRecipient, uint256 msgValue, bytes memory zapRecipientCallData) internal {
        // Perform the low-level call to ZapRecipient, bubbling up any revert reason.
        bytes memory returnData =
            Address.functionCallWithValue({target: zapRecipient, data: zapRecipientCallData, value: msgValue});

        // Explicit revert if no return data at all.
        if (returnData.length == 0) revert SIR__ZapNoReturnValue();
        // Check that exactly a single return value was returned.
        if (returnData.length != 32) revert SIR__ZapIncorrectReturnValue();
        // Return value should be abi-encoded hook function selector.
        if (bytes32(returnData) != bytes32(IZapRecipient.zap.selector)) {
            revert SIR__ZapIncorrectReturnValue();
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;

interface ISynapseIntentRouter {
    /// @notice Parameters for a single Zap step.
    /// @param token    Address of the token to use for the step
    /// @param amount   Amount of tokens to use for the step (type(uint256).max to use the full ZapRecipient balance)
    /// @param msgValue Amount of native token to supply for the step, out of the total `msg.value` used for the
    ///                 `fulfillIntent` call (could differ from `amount` regardless of the token type)
    /// @param zapData  Instructions for the ZapRecipient contract on how to execute the Zap
    struct StepParams {
        address token;
        uint256 amount;
        uint256 msgValue;
        bytes zapData;
    }

    /// @notice Kindly ask SIR to complete the provided intent by completing a series of Zap steps using the
    /// provided ZapRecipient contract.
    /// - Each step is verified to be a correct Zap as per `IZapRecipient` specification.
    /// - The amounts used for each step can be predetermined or based on the proceeds from the previous steps.
    /// - SIR does not perform any checks on the Zap Data; the user is responsible for ensuring correct encoding.
    /// - The user is responsible for selecting the correct ZapRecipient for their intent: ZapRecipient must be
    ///   able to modify the Zap Data to adjust to possible changes in the passed amount value.
    /// - SIR checks that the ZapRecipient balance for every token in `steps` has not increased after the last step.
    /// - SIR does not perform any slippage checks. If required, the slippage settings must be embedded in any of
    ///   the Zap steps to be used by ZapRecipient.
    /// @dev Typical workflow involves a series of preparation steps followed by the last step representing the user
    /// intent such as bridging, depositing, or a simple transfer to the final recipient. The ZapRecipient must be
    /// the funds recipient for the preparation steps, while the final recipient must be used for the last step.
    /// @dev This function will revert in any of the following cases:
    /// - The deadline has passed.
    /// - The array of StepParams is empty.
    /// - Any step fails.
    /// - `msg.value` does not match `sum(steps[i].msgValue)`.
    /// @param zapRecipient         Address of the IZapRecipient contract to use for the Zap steps
    /// @param amountIn             Initial amount of tokens (steps[0].token) to transfer into ZapRecipient
    /// @param deadline             Deadline for the intent to be completed
    /// @param steps                Parameters for each step. Use amount = type(uint256).max for steps that
    ///                             should use the full ZapRecipient balance.
    function completeIntentWithBalanceChecks(
        address zapRecipient,
        uint256 amountIn,
        uint256 deadline,
        StepParams[] memory steps
    )
        external
        payable;

    /// @notice Kindly ask SIR to complete the provided intent by completing a series of Zap steps using the
    /// provided ZapRecipient contract.
    /// @dev This function is identical to `completeIntentWithBalanceChecks` except that it does not verify that
    /// the ZapRecipient balance for every token in `steps` has not increased after the last Zap.
    /// Anyone using this function must validate that the funds are fully spent by ZapRecipient
    /// using other means like separate on-chain checks or off-chain simulation.
    function completeIntent(
        address zapRecipient,
        uint256 amountIn,
        uint256 deadline,
        StepParams[] memory steps
    )
        external
        payable;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;

interface ISynapseIntentRouterErrors {
    error SIR__DeadlineExceeded();
    error SIR__MsgValueIncorrect();
    error SIR__StepsNotProvided();
    error SIR__TokenNotContract();
    error SIR__UnspentFunds();
    error SIR__ZapIncorrectReturnValue();
    error SIR__ZapNoReturnValue();
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;

/// @notice Interface for contracts that can perform Zap operations. Such contracts could be used as Recipients
/// in a FastBridge transaction that includes a Zap operation. The Zap Data should include instructions on how
/// exactly the Zap operation should be executed, which would typically include the target address and calldata
/// to use. The exact implementation of the Zap Data encoding is up to the Recipient contract.
interface IZapRecipient {
    /// @notice Performs a Zap operation with the given token and amount according to the provided Zap data.
    /// @param token    The address of the token being used for the Zap operation.
    /// @param amount   The amount of tokens to be used.
    /// @param zapData  The encoded data specifying how the Zap operation should be executed.
    /// @return         The function selector to indicate successful execution.
    function zap(address token, uint256 amount, bytes memory zapData) external payable returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

{
  "remappings": [
    "@openzeppelin/=node_modules/@openzeppelin/",
    "@synapsecns/=node_modules/@synapsecns/",
    "forge-std/=node_modules/forge-std/src/"
  ],
  "optimizer": {
    "enabled": true,
    "runs": 1000000
  },
  "metadata": {
    "useLiteralContent": false,
    "bytecodeHash": "ipfs",
    "appendCBOR": true
  },
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  },
  "evmVersion": "paris",
  "viaIR": false,
  "libraries": {}
}

• No Contract Security Audit Submitted- Submit Audit Here

[{"inputs":[{"internalType":"address","name":"target","type":"address"}],"name":"AddressEmptyCode","type":"error"},{"inputs":[{"internalType":"address","name":"account","type":"address"}],"name":"AddressInsufficientBalance","type":"error"},{"inputs":[],"name":"FailedInnerCall","type":"error"},{"inputs":[],"name":"SIR__DeadlineExceeded","type":"error"},{"inputs":[],"name":"SIR__MsgValueIncorrect","type":"error"},{"inputs":[],"name":"SIR__StepsNotProvided","type":"error"},{"inputs":[],"name":"SIR__TokenNotContract","type":"error"},{"inputs":[],"name":"SIR__UnspentFunds","type":"error"},{"inputs":[],"name":"SIR__ZapIncorrectReturnValue","type":"error"},{"inputs":[],"name":"SIR__ZapNoReturnValue","type":"error"},{"inputs":[{"internalType":"address","name":"token","type":"address"}],"name":"SafeERC20FailedOperation","type":"error"},{"inputs":[],"name":"NATIVE_GAS_TOKEN","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"zapRecipient","type":"address"},{"internalType":"uint256","name":"amountIn","type":"uint256"},{"internalType":"uint256","name":"deadline","type":"uint256"},{"components":[{"internalType":"address","name":"token","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"},{"internalType":"uint256","name":"msgValue","type":"uint256"},{"internalType":"bytes","name":"zapData","type":"bytes"}],"internalType":"struct ISynapseIntentRouter.StepParams[]","name":"steps","type":"tuple[]"}],"name":"completeIntent","outputs":[],"stateMutability":"payable","type":"function"},{"inputs":[{"internalType":"address","name":"zapRecipient","type":"address"},{"internalType":"uint256","name":"amountIn","type":"uint256"},{"internalType":"uint256","name":"deadline","type":"uint256"},{"components":[{"internalType":"address","name":"token","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"},{"internalType":"uint256","name":"msgValue","type":"uint256"},{"internalType":"bytes","name":"zapData","type":"bytes"}],"internalType":"struct ISynapseIntentRouter.StepParams[]","name":"steps","type":"tuple[]"}],"name":"completeIntentWithBalanceChecks","outputs":[],"stateMutability":"payable","type":"function"}]

0x608060405234801561001057600080fd5b50610f77806100206000396000f3fe6080604052600436106100345760003560e01c80630f862f1e14610039578063c2d048d71461008a578063d4a585371461009f575b600080fd5b34801561004557600080fd5b5061006173eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee81565b60405173ffffffffffffffffffffffffffffffffffffffff909116815260200160405180910390f35b61009d610098366004610c2d565b6100b2565b005b61009d6100ad366004610c2d565b6103d9565b8060008167ffffffffffffffff8111156100ce576100ce610cc4565b6040519080825280602002602001820160405280156100f7578160200160208202803683370190505b50905060005b8281101561024057600085858381811061011957610119610cf3565b905060200281019061012b9190610d22565b610139906020810190610d60565b905073ffffffffffffffffffffffffffffffffffffffff811673eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee14610201576040517f70a0823100000000000000000000000000000000000000000000000000000000815273ffffffffffffffffffffffffffffffffffffffff8a811660048301528216906370a0823190602401602060405180830381865afa1580156101d8573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906101fc9190610d7b565b61021a565b8873ffffffffffffffffffffffffffffffffffffffff16315b83838151811061022c5761022c610cf3565b6020908102919091010152506001016100fd565b5061024e87878787876103d9565b60005b828110156103cf57600085858381811061026d5761026d610cf3565b905060200281019061027f9190610d22565b61028d906020810190610d60565b9050600073ffffffffffffffffffffffffffffffffffffffff821673eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee14610357576040517f70a0823100000000000000000000000000000000000000000000000000000000815273ffffffffffffffffffffffffffffffffffffffff8b811660048301528316906370a0823190602401602060405180830381865afa15801561032e573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906103529190610d7b565b610370565b8973ffffffffffffffffffffffffffffffffffffffff16315b905083838151811061038457610384610cf3565b60200260200101518111156103c5576040517fd93cacc700000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b5050600101610251565b5050505050505050565b8042841015610414576040517f30f753ab00000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b8060000361044e576040517f89c9640300000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b61048b868484600081811061046557610465610cf3565b90506020028101906104779190610d22565b610485906020810190610d60565b8761074d565b6000805b828110156107095760008585838181106104ab576104ab610cf3565b90506020028101906104bd9190610d22565b6104cb906020810190610d60565b905060008686848181106104e1576104e1610cf3565b90506020028101906104f39190610d22565b60400135905086868481811061050b5761050b610cf3565b905060200281019061051d9190610d22565b6020013598507fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff89036106345773ffffffffffffffffffffffffffffffffffffffff821673eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee14610610576040517f70a0823100000000000000000000000000000000000000000000000000000000815273ffffffffffffffffffffffffffffffffffffffff8b811660048301528316906370a0823190602401602060405180830381865afa1580156105e7573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061060b9190610d7b565b610631565b6106318173ffffffffffffffffffffffffffffffffffffffff8c1631610d94565b98505b6106fb8a82848c8b8b8981811061064d5761064d610cf3565b905060200281019061065f9190610d22565b61066d906060810190610dce565b6040516024016106809493929190610e3a565b604080517fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe08184030181529190526020810180517bffffffffffffffffffffffffffffffffffffffffffffffffffffffff167fe85e13dd0000000000000000000000000000000000000000000000000000000017905261083b565b92909201915060010161048f565b5034811015610744576040517fa320a1a300000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b50505050505050565b7fffffffffffffffffffffffff111111111111111111111111111111111111111273ffffffffffffffffffffffffffffffffffffffff8316016107c8573481146107c3576040517fa320a1a300000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b505050565b8173ffffffffffffffffffffffffffffffffffffffff163b600003610819576040517f35f772ef00000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b6107c373ffffffffffffffffffffffffffffffffffffffff8316338584610927565b60006108488483856109bc565b90508051600003610885576040517f423da18f00000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b80516020146108c0576040517f7c373a5900000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b7fe85e13dd000000000000000000000000000000000000000000000000000000006108ea82610eab565b14610921576040517f7c373a5900000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b50505050565b6040805173ffffffffffffffffffffffffffffffffffffffff85811660248301528416604482015260648082018490528251808303909101815260849091019091526020810180517bffffffffffffffffffffffffffffffffffffffffffffffffffffffff167f23b872dd00000000000000000000000000000000000000000000000000000000179052610921908590610a86565b6060814710156109ff576040517fcd7860590000000000000000000000000000000000000000000000000000000081523060048201526024015b60405180910390fd5b6000808573ffffffffffffffffffffffffffffffffffffffff168486604051610a289190610ef0565b60006040518083038185875af1925050503d8060008114610a65576040519150601f19603f3d011682016040523d82523d6000602084013e610a6a565b606091505b5091509150610a7a868383610b1c565b925050505b9392505050565b6000610aa873ffffffffffffffffffffffffffffffffffffffff841683610bab565b90508051600014158015610acd575080806020019051810190610acb9190610f1f565b155b156107c3576040517f5274afe700000000000000000000000000000000000000000000000000000000815273ffffffffffffffffffffffffffffffffffffffff841660048201526024016109f6565b606082610b3157610b2c82610bc2565b610a7f565b8151158015610b55575073ffffffffffffffffffffffffffffffffffffffff84163b155b15610ba4576040517f9996b31500000000000000000000000000000000000000000000000000000000815273ffffffffffffffffffffffffffffffffffffffff851660048201526024016109f6565b5080610a7f565b6060610bb9838360006109bc565b90505b92915050565b805115610bd25780518082602001fd5b6040517f1425ea4200000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b803573ffffffffffffffffffffffffffffffffffffffff81168114610c2857600080fd5b919050565b600080600080600060808688031215610c4557600080fd5b610c4e86610c04565b94506020860135935060408601359250606086013567ffffffffffffffff80821115610c7957600080fd5b818801915088601f830112610c8d57600080fd5b813581811115610c9c57600080fd5b8960208260051b8501011115610cb157600080fd5b9699959850939650602001949392505050565b7f4e487b7100000000000000000000000000000000000000000000000000000000600052604160045260246000fd5b7f4e487b7100000000000000000000000000000000000000000000000000000000600052603260045260246000fd5b600082357fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff81833603018112610d5657600080fd5b9190910192915050565b600060208284031215610d7257600080fd5b610bb982610c04565b600060208284031215610d8d57600080fd5b5051919050565b80820180821115610bbc577f4e487b7100000000000000000000000000000000000000000000000000000000600052601160045260246000fd5b60008083357fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe1843603018112610e0357600080fd5b83018035915067ffffffffffffffff821115610e1e57600080fd5b602001915036819003821315610e3357600080fd5b9250929050565b73ffffffffffffffffffffffffffffffffffffffff8516815283602082015260606040820152816060820152818360808301376000818301608090810191909152601f9092017fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe01601019392505050565b80516020808301519190811015610eea577fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8160200360031b1b821691505b50919050565b6000825160005b81811015610f115760208186018101518583015201610ef7565b506000920191825250919050565b600060208284031215610f3157600080fd5b81518015158114610a7f57600080fdfea26469706673582212205769c635ee40c027d80bbab0e4f6f909281c5a47de2e93245a6bd76c36d2377d64736f6c63430008180033

0x6080604052600436106100345760003560e01c80630f862f1e14610039578063c2d048d71461008a578063d4a585371461009f575b600080fd5b34801561004557600080fd5b5061006173eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee81565b60405173ffffffffffffffffffffffffffffffffffffffff909116815260200160405180910390f35b61009d610098366004610c2d565b6100b2565b005b61009d6100ad366004610c2d565b6103d9565b8060008167ffffffffffffffff8111156100ce576100ce610cc4565b6040519080825280602002602001820160405280156100f7578160200160208202803683370190505b50905060005b8281101561024057600085858381811061011957610119610cf3565b905060200281019061012b9190610d22565b610139906020810190610d60565b905073ffffffffffffffffffffffffffffffffffffffff811673eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee14610201576040517f70a0823100000000000000000000000000000000000000000000000000000000815273ffffffffffffffffffffffffffffffffffffffff8a811660048301528216906370a0823190602401602060405180830381865afa1580156101d8573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906101fc9190610d7b565b61021a565b8873ffffffffffffffffffffffffffffffffffffffff16315b83838151811061022c5761022c610cf3565b6020908102919091010152506001016100fd565b5061024e87878787876103d9565b60005b828110156103cf57600085858381811061026d5761026d610cf3565b905060200281019061027f9190610d22565b61028d906020810190610d60565b9050600073ffffffffffffffffffffffffffffffffffffffff821673eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee14610357576040517f70a0823100000000000000000000000000000000000000000000000000000000815273ffffffffffffffffffffffffffffffffffffffff8b811660048301528316906370a0823190602401602060405180830381865afa15801561032e573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906103529190610d7b565b610370565b8973ffffffffffffffffffffffffffffffffffffffff16315b905083838151811061038457610384610cf3565b60200260200101518111156103c5576040517fd93cacc700000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b5050600101610251565b5050505050505050565b8042841015610414576040517f30f753ab00000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b8060000361044e576040517f89c9640300000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b61048b868484600081811061046557610465610cf3565b90506020028101906104779190610d22565b610485906020810190610d60565b8761074d565b6000805b828110156107095760008585838181106104ab576104ab610cf3565b90506020028101906104bd9190610d22565b6104cb906020810190610d60565b905060008686848181106104e1576104e1610cf3565b90506020028101906104f39190610d22565b60400135905086868481811061050b5761050b610cf3565b905060200281019061051d9190610d22565b6020013598507fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff89036106345773ffffffffffffffffffffffffffffffffffffffff821673eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee14610610576040517f70a0823100000000000000000000000000000000000000000000000000000000815273ffffffffffffffffffffffffffffffffffffffff8b811660048301528316906370a0823190602401602060405180830381865afa1580156105e7573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061060b9190610d7b565b610631565b6106318173ffffffffffffffffffffffffffffffffffffffff8c1631610d94565b98505b6106fb8a82848c8b8b8981811061064d5761064d610cf3565b905060200281019061065f9190610d22565b61066d906060810190610dce565b6040516024016106809493929190610e3a565b604080517fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe08184030181529190526020810180517bffffffffffffffffffffffffffffffffffffffffffffffffffffffff167fe85e13dd0000000000000000000000000000000000000000000000000000000017905261083b565b92909201915060010161048f565b5034811015610744576040517fa320a1a300000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b50505050505050565b7fffffffffffffffffffffffff111111111111111111111111111111111111111273ffffffffffffffffffffffffffffffffffffffff8316016107c8573481146107c3576040517fa320a1a300000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b505050565b8173ffffffffffffffffffffffffffffffffffffffff163b600003610819576040517f35f772ef00000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b6107c373ffffffffffffffffffffffffffffffffffffffff8316338584610927565b60006108488483856109bc565b90508051600003610885576040517f423da18f00000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b80516020146108c0576040517f7c373a5900000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b7fe85e13dd000000000000000000000000000000000000000000000000000000006108ea82610eab565b14610921576040517f7c373a5900000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b50505050565b6040805173ffffffffffffffffffffffffffffffffffffffff85811660248301528416604482015260648082018490528251808303909101815260849091019091526020810180517bffffffffffffffffffffffffffffffffffffffffffffffffffffffff167f23b872dd00000000000000000000000000000000000000000000000000000000179052610921908590610a86565b6060814710156109ff576040517fcd7860590000000000000000000000000000000000000000000000000000000081523060048201526024015b60405180910390fd5b6000808573ffffffffffffffffffffffffffffffffffffffff168486604051610a289190610ef0565b60006040518083038185875af1925050503d8060008114610a65576040519150601f19603f3d011682016040523d82523d6000602084013e610a6a565b606091505b5091509150610a7a868383610b1c565b925050505b9392505050565b6000610aa873ffffffffffffffffffffffffffffffffffffffff841683610bab565b90508051600014158015610acd575080806020019051810190610acb9190610f1f565b155b156107c3576040517f5274afe700000000000000000000000000000000000000000000000000000000815273ffffffffffffffffffffffffffffffffffffffff841660048201526024016109f6565b606082610b3157610b2c82610bc2565b610a7f565b8151158015610b55575073ffffffffffffffffffffffffffffffffffffffff84163b155b15610ba4576040517f9996b31500000000000000000000000000000000000000000000000000000000815273ffffffffffffffffffffffffffffffffffffffff851660048201526024016109f6565b5080610a7f565b6060610bb9838360006109bc565b90505b92915050565b805115610bd25780518082602001fd5b6040517f1425ea4200000000000000000000000000000000000000000000000000000000815260040160405180910390fd5b803573ffffffffffffffffffffffffffffffffffffffff81168114610c2857600080fd5b919050565b600080600080600060808688031215610c4557600080fd5b610c4e86610c04565b94506020860135935060408601359250606086013567ffffffffffffffff80821115610c7957600080fd5b818801915088601f830112610c8d57600080fd5b813581811115610c9c57600080fd5b8960208260051b8501011115610cb157600080fd5b9699959850939650602001949392505050565b7f4e487b7100000000000000000000000000000000000000000000000000000000600052604160045260246000fd5b7f4e487b7100000000000000000000000000000000000000000000000000000000600052603260045260246000fd5b600082357fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff81833603018112610d5657600080fd5b9190910192915050565b600060208284031215610d7257600080fd5b610bb982610c04565b600060208284031215610d8d57600080fd5b5051919050565b80820180821115610bbc577f4e487b7100000000000000000000000000000000000000000000000000000000600052601160045260246000fd5b60008083357fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe1843603018112610e0357600080fd5b83018035915067ffffffffffffffff821115610e1e57600080fd5b602001915036819003821315610e3357600080fd5b9250929050565b73ffffffffffffffffffffffffffffffffffffffff8516815283602082015260606040820152816060820152818360808301376000818301608090810191909152601f9092017fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe01601019392505050565b80516020808301519190811015610eea577fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8160200360031b1b821691505b50919050565b6000825160005b81811015610f115760208186018101518583015201610ef7565b506000920191825250919050565b600060208284031215610f3157600080fd5b81518015158114610a7f57600080fdfea26469706673582212205769c635ee40c027d80bbab0e4f6f909281c5a47de2e93245a6bd76c36d2377d64736f6c63430008180033