Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.20;

import {ERC20} from "../ERC20.sol";
import {Context} from "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys a `value` amount of tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 value) public virtual {
        _burn(_msgSender(), value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, deducting from
     * the caller's allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `value`.
     */
    function burnFrom(address account, uint256 value) public virtual {
        _spendAllowance(account, _msgSender(), value);
        _burn(account, value);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

import "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

import "./lib/SafeMath.sol";
import "./interfaces/IRewardManager.sol";
import "./interfaces/IUniswapV2Router02.sol";
import "./interfaces/IUniswapV2Factory.sol";

contract DNA is ERC20Burnable, Ownable {
    using SafeMath for *;

    // UniswapV2 Router Address
    IUniswapV2Router02 public immutable uniswapV2Router;

    // Pair Address
    address public immutable uniswapV2Pair;

    // Deployer or Owner address
    address public immutable ownerAddress;
    address public companyWalletAddress;

    // Check if trading is open.
    bool public tradingOpen = false;

    // Tax Percentage
    uint8 public constant initialTransferTaxForRegisteredUser = 15;
    uint8 public transferTaxForRegisteredUser = initialTransferTaxForRegisteredUser;
    uint8 public evolutionPoolShareForRegisteredUser = 5;
    uint8 public referralShareForRegisteredUser = 1;

    uint8 public constant initialTransferTaxForUnregisteredUser = 15;
    uint8 public transferTaxForUnregisteredUser = initialTransferTaxForUnregisteredUser;
    uint8 public evolutionPoolShareForUnregisteredUser = 5;

    // Limits
    uint256 public immutable maxBuyAmount;
    uint256 public immutable maxSellAmount;
    uint256 public immutable maxWalletAmount;
    bool public limitsInEffect = true;

    // Reward Manger
    IRewardManager public rewardManager;

    // exclude from fees and max transaction amount
    mapping(address => bool) private _isExcludedFromFees;
    mapping(address => bool) private _isExcludedMaxTransactionAmount;

    // store addresses that a automatic market maker pairs. Any transfer *to* these addresses
    // could be subject to a maximum transfer amount
    mapping(address => bool) public automatedMarketMakerPairs;

    // Events
    event SetAutomatedMarketMakerPair(address pair, bool value);
    event LimitsUpdated(
        uint256 newBuyAmount,
        uint256 newSellAmount,
        uint256 newWalletAmount
    );
    event MaxTransactionExclusion(address indexed _address, bool excluded);
    event DistributedReferralReward(address from, address referrerAddress, uint256 referrerShareAmount);

    // Errors
    error OnlyOwner();
    error ZeroAddress();
    error InsufficientBalance();
    error InvalidValue();
    error TradingInActive();
    error TradingOpen();
    error PairAlreadyAdded();
    error CannotRemovePair();
    error BuyLimitExceeded();
    error SellLimitExceeded();
    error MaxWalletLimitExceeded();
    error TaxCannotIncrease();

    constructor(
        uint256 _totalSupply,
        address _companyWalletAddress,
        address _uniswapRouterAddress
    ) ERC20("DNAToken", "DNA") Ownable(_msgSender()) {
        _mint(_msgSender(), _totalSupply.mul(10 ** decimals()));
        ownerAddress = _msgSender();

        uniswapV2Router = IUniswapV2Router02(_uniswapRouterAddress);
        _excludeFromMaxTransaction(_uniswapRouterAddress, true);

        uniswapV2Pair = IUniswapV2Factory(uniswapV2Router.factory()).createPair(
                address(this),
                uniswapV2Router.WETH()
            );

        maxBuyAmount = ((_totalSupply.mul(10 ** decimals())).mul(2)).div(1000); // 0.2%
        maxSellAmount = ((_totalSupply.mul(10 ** decimals())).mul(2)).div(1000); // 0.2%
        maxWalletAmount = ((_totalSupply.mul(10 ** decimals())).mul(6)).div(1000); // 0.6%

        excludeFromFees(_msgSender(), true);
        excludeFromFees(address(this), true);
        excludeFromFees(address(0xdead), true);

        companyWalletAddress = _companyWalletAddress;
        excludeFromFees(companyWalletAddress, true);
        _excludeFromMaxTransaction(companyWalletAddress, true);

        _setAutomatedMarketMakerPair(address(uniswapV2Pair), true); // setting pair address as AMM pair

        _excludeFromMaxTransaction(_msgSender(), true);
        _excludeFromMaxTransaction(address(this), true);
        _excludeFromMaxTransaction(address(0xdead), true);
    }

    function setCompanyWalletAddress(
        address _companyWalletAddress
    ) external onlyOwner {
        if (_companyWalletAddress == address(0)) {
            revert ZeroAddress();
        }

        companyWalletAddress = _companyWalletAddress;
        excludeFromFees(companyWalletAddress, true);
        _excludeFromMaxTransaction(companyWalletAddress, true);
    }

    // Set AMM pairs
    function setAutomatedMarketMakerPair(
        address pair,
        bool value
    ) external {
        if (_msgSender() != ownerAddress) {
            revert OnlyOwner();
        }
        if (pair == uniswapV2Pair) {
            revert PairAlreadyAdded();
        }

        _setAutomatedMarketMakerPair(pair, value);
    }

    // Exclude addresses from max transaction limit
    function excludeFromMaxTransaction(
        address _account,
        bool _exclude   
    ) external {
        if (_msgSender() != ownerAddress) {
            revert OnlyOwner();
        }
        if (!_exclude) {
            // Cannot exclude pair address
            if (_account == uniswapV2Pair) {
                revert CannotRemovePair();
            }
        }
        _excludeFromMaxTransaction(_account, _exclude);
    }

    // Exclude addresses from tax
    function excludeFromFees(address account, bool excluded) public {
        if (_msgSender() != ownerAddress) {
            revert OnlyOwner();
        }
        _isExcludedFromFees[account] = excluded;
    }

    // Update verified user transfer taxes
    // 6, 5, 1
    function updateRegisteredUserTax(
        uint8 _transferTaxForRegisteredUser,
        uint8 _evolutionPoolShareForRegisteredUser,
        uint8 _referralShareForRegisteredUser
    ) external onlyOwner {
        // Total tax cannot be less than the sum of different taxes for registered user
        if (
            _evolutionPoolShareForRegisteredUser +
                _referralShareForRegisteredUser >
            _transferTaxForRegisteredUser
        ) {
            revert InvalidValue();
        }

        // New tax amount cannot be more than the current tax amount
        if (_transferTaxForRegisteredUser > initialTransferTaxForRegisteredUser) {
            revert TaxCannotIncrease();
        }

        referralShareForRegisteredUser = _referralShareForRegisteredUser;
        evolutionPoolShareForRegisteredUser = _evolutionPoolShareForRegisteredUser;
        transferTaxForRegisteredUser = _transferTaxForRegisteredUser;
    }

    // Update unverified user transfer taxes
    // 10 and 5
    function updateUnregisteredUserTax(
        uint8 _transferTaxForUnregisteredUser,
        uint8 _evolutionPoolShareForUnregisteredUser
    ) external onlyOwner {
        // Total tax cannot be less than the sum of different taxes for unregistered user
        if (
            _evolutionPoolShareForUnregisteredUser >
            _transferTaxForUnregisteredUser
        ) {
            revert InvalidValue();
        }

        // New tax amount cannot be more than the current tax amount
        if (_transferTaxForUnregisteredUser > initialTransferTaxForUnregisteredUser) {
            revert TaxCannotIncrease();
        }

        evolutionPoolShareForUnregisteredUser = _evolutionPoolShareForUnregisteredUser;
        transferTaxForUnregisteredUser = _transferTaxForUnregisteredUser;
    }

    // remove limits after token is stable
    function removeLimits() external onlyOwner {
        limitsInEffect = false;
    }

    function transfer(
        address to,
        uint256 amount
    ) public override returns (bool) {
        _safeTransfer(_msgSender(), to, amount);
        return true;
    }

    function transferFrom(
        address from,
        address to,
        uint256 value
    ) public override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _safeTransfer(from, to, value);
        return true;
    }

    // Enables the trading.
    // Once enabled, can never be turned off
    function enableTrading() external onlyOwner {
        if (tradingOpen) {
            revert TradingOpen();
        }
        tradingOpen = true;
    }

    // Recover any tokens transferred to token address
    function recoverTokens(
        address _token,
        address _to,
        uint256 _value
    ) external {
        if (_msgSender() != ownerAddress) {
            revert OnlyOwner();
        }

        if (_token == address(0) || _to == address(0)) {
            revert ZeroAddress();
        }

        if (_value == 0) {
            revert InvalidValue();
        }

        uint256 _contractBalance = ERC20(_token).balanceOf(address(this));
        if (_value > _contractBalance) {
            revert InsufficientBalance();
        }
        ERC20(_token).transfer(_to, _contractBalance);
    }

    // withdraw ETH if stuck or someone sends to the address
    function recoverETH(
        address _to,
        uint256 _value
    ) external returns (bool success) {
        if (_msgSender() != ownerAddress) {
            revert OnlyOwner();
        }

        if(_to == address(0)){
            revert ZeroAddress();
        }

        if (_value == 0) {
            revert InvalidValue();
        }

        if(_value > address(this).balance){
            revert InsufficientBalance();
        }

        (success, ) = payable(address(_to)).call{value: _value}("");
    }

    // This function will set the addres for rewardManager
    function setRewardManager(address _rewardManager) external onlyOwner {
        if (_rewardManager == address(0)) {
            revert ZeroAddress();
        }

        rewardManager = IRewardManager(_rewardManager);
        excludeFromFees(_rewardManager, true);
    }

    function isUserExcludedFromFees(address _account) external view returns(bool){
        return _isExcludedFromFees[_account];
    }

    function isUserExcludedFromMaxTransactionAmount(address _account) external view returns(bool){
        return _isExcludedMaxTransactionAmount[_account];
    }

    function _safeTransfer(address from, address to, uint256 amount) private {
        if (from == address(0)) {
            revert ZeroAddress();
        }

        if (to == address(0)) {
            revert ZeroAddress();
        }

        if (amount == 0) {
            revert InvalidValue();
        }

        // Till limits are not removed
        if (limitsInEffect) {
            if (from != owner() && to != owner()) {
                // Only owner can transfer the tokens before trading is enabled
                if (!tradingOpen) {
                    revert TradingInActive();
                }
                //when buy
                if (
                    automatedMarketMakerPairs[from] &&
                    !_isExcludedMaxTransactionAmount[to]
                ) {
                    // Check max buy limit
                    if (amount > maxBuyAmount) {
                       revert BuyLimitExceeded();
                    }

                    // Checks max wallet limit
                    if (amount.add(balanceOf(to)) > maxWalletAmount) {
                        revert MaxWalletLimitExceeded();
                    }
                }
                //when sell
                else if (
                    automatedMarketMakerPairs[to] &&
                    !_isExcludedMaxTransactionAmount[from]
                ) {
                    // Checks max sell limit
                    if (amount > maxSellAmount) {
                        revert SellLimitExceeded();
                    }
                }
                //when transfer
                    else if (
                    !_isExcludedMaxTransactionAmount[from]
                    ){
                    if (amount.add(balanceOf(to)) > maxWalletAmount) {
                        // Checks max wallet limit
                        revert MaxWalletLimitExceeded();
                    }
                }
            }
        }

        uint256 fees = 0;

        // Tax will be deducted only when trading is open, and will not be applied if the address is whitelisted.
        if (
            tradingOpen &&
            !_isExcludedFromFees[from] &&
            !_isExcludedFromFees[to]
        ) {
            fees = _calculateAndTransferTax(from, to, amount);
        }

        super._transfer(from, to, amount.sub(fees));
    }

    // Calculates the tax payments, transfers the tax and returns total tax deducted.
    function _calculateAndTransferTax(
        address from,
        address to,
        uint256 amount
    ) private returns (uint256) {
        address referrer;
        address addressToCheck = from;

        if (automatedMarketMakerPairs[from]) {
            addressToCheck = to;
        }

        // checking if address is registered
        if (rewardManager.isAccountRegistered(addressToCheck)) {
            referrer = rewardManager.getReferrerAddress(addressToCheck);
        }

        return _processTaxPayment(from, referrer, amount);
    }

    // Transfers the tax amount and returns the total tax deducted
    function _processTaxPayment(
        address _from,
        address _referrerAddress,
        uint256 _amount
    ) private returns (uint256) {
        // Tax Percentage transfer to rewardManager to distribute the tokens as rewards
        uint8 evolutionPoolShare;

        // Tax Percentage transfer to referrer as rewards.
        uint8 referrerShare;

        // Tax Percentage transfer to company Wallet as rewards.
        uint8 companyWalletShare;

        // Address to transfer ( can be referrer address )
        address referrerAddress;

        // If participant is registered and referrer is not zero address
        if (_referrerAddress != address(0)) {
            evolutionPoolShare = evolutionPoolShareForRegisteredUser;

            // If user is registered, the rewards will be transferred to referrer.
            referrerAddress = _referrerAddress;

            // Referrer Share will be the amount transferring to referral address of the sender.
            referrerShare = referralShareForRegisteredUser;

            // Company wallet share will be the amount transferring to company wallet address in the initial phase.
            companyWalletShare = uint8(
                (transferTaxForRegisteredUser)
                    .sub(evolutionPoolShareForRegisteredUser)
                    .sub(referralShareForRegisteredUser)
            );
        } else {
            evolutionPoolShare = evolutionPoolShareForUnregisteredUser;

            // If initial block limit is passed, Apply unverifiedUserTaxToOwner ((transferTaxForUnregisteredUser) - evolutionPoolShareForUnregisteredUser
            companyWalletShare = uint8(
                (transferTaxForUnregisteredUser).sub(
                    evolutionPoolShareForUnregisteredUser
                )
            );
        }

        // Calculating amount to transfer to rewrdManager.
        uint256 evolutionPoolShareAmount = _amount.mul(evolutionPoolShare).div(
            100
        );

        // Calculating amount to transfer to owner/referrer.
        uint256 referrerShareAmount = _amount.mul(referrerShare).div(100);

        // Calculating amount to transfer to company wallet
        uint256 companyWalletShareAmount = _amount.mul(companyWalletShare).div(
            100
        );

        // Transferring the rewards to referrer
        if (referrerShareAmount > 0) {
            super._transfer(_from, referrerAddress, referrerShareAmount);
            emit DistributedReferralReward(_from, referrerAddress, referrerShareAmount);
        }

        // Transferring the rewards to company wallet
        if (companyWalletShareAmount > 0) {
            super._transfer(
                _from,
                companyWalletAddress,
                companyWalletShareAmount
            );
        }

        // Transferring the rewards to rewardManager and distributing the rewards.
        if (evolutionPoolShareAmount > 0) {
            super._transfer(
                _from,
                address(rewardManager),
                evolutionPoolShareAmount
            );
            rewardManager.distributeRewards(evolutionPoolShareAmount);
        }

        // Returning totalTax Amount transferred or deducted.
        return
            evolutionPoolShareAmount.add(referrerShareAmount).add(
                companyWalletShareAmount
            );
    }

    // Sets AMM pairs
    function _setAutomatedMarketMakerPair(address pair, bool value) private {
        automatedMarketMakerPairs[pair] = value;

        _excludeFromMaxTransaction(pair, value);

        emit SetAutomatedMarketMakerPair(pair, value);
    }

    // Excludes address from max transaction limit
    function _excludeFromMaxTransaction(
        address updAds,
        bool isExcluded
    ) private {
        _isExcludedMaxTransactionAmount[updAds] = isExcluded;
        emit MaxTransactionExclusion(updAds, isExcluded);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

interface IRewardManager {
    function getReferrerAddress(
        address _account
    ) external view returns (address);

    function isAccountRegistered(address _account) external view returns (bool);

    function distributeRewards(uint256 _taxAmount) external;

    function updateLevel(address _account) external;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

interface IUniswapV2Factory {
    function createPair(address tokenA, address tokenB)
        external
        returns (address pair);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

interface IUniswapV2Router02 {
    function swapExactETHForTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable returns (uint[] memory amounts);
    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
    function factory() external pure returns (address);
    function WETH() external pure returns (address);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

/**
 * @title SafeMath
 * @dev Unsigned math operations with safety checks that revert on error
 */
library SafeMath {
    /**
    * @dev Multiplies two unsigned integers, reverts on overflow.
    */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b);

        return c;
    }

    /**
    * @dev Integer division of two unsigned integers truncating the quotient, reverts on division by zero.
    */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
    * @dev Subtracts two unsigned integers, reverts on overflow (i.e. if subtrahend is greater than minuend).
    */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a);
        uint256 c = a - b;

        return c;
    }

    /**
    * @dev Adds two unsigned integers, reverts on overflow.
    */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a);

        return c;
    }
}